ASP实现备份、压缩、还原数据库

sub BackupData()
 dim bkfolder,bkdbname,fso
 bkfolder=trim(request("bkfolder"))     'bkfolder是备份目录
 bkdbname=trim(request("bkdbname"))  'bkdbname是备份文件名
 if bkfolder="" then
  FoundErr=True
  ErrMsg=ErrMsg & "<li>请指定备份目录！"
 end if
 if bkdbname="" then
  FoundErr=True
  ErrMsg=ErrMsg & "<li>请指定备份文件名</li>"
 end if
 if FoundErr=True then exit sub
 bkfolder=server.MapPath(bkfolder)
 Set Fso=server.createobject("scripting.filesystemobject")
 if fso.FileExists(dbpath) then
  If fso.FolderExists(bkfolder)=false Then
   fso.CreateFolder(bkfolder)
  end if
  fso.copyfile dbpath,bkfolder & "\" & bkdbname & ".asa"
  response.write "<center>备份数据库成功，备份的数据库为 " & bkfolder & "\" & bkdbname & ".asa</center>"
 Else
  response.write "<center>找不到源数据库文件。</center>"
 End if
end sub

sub CompactData()
 Dim fso, Engine, strDBPath
 strDBPath = left(dbPath,instrrev(DBPath,"\"))
 Set fso = Server.CreateObject("Scripting.FileSystemObject")
 If fso.FileExists(dbPath) Then
  Set Engine = CreateObject("JRO.JetEngine")
  Engine.CompactDatabase "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & dbpath," Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDBPath & "temp.mdb"
  fso.CopyFile strDBPath & "temp.mdb",dbpath
  fso.DeleteFile(strDBPath & "temp.mdb")
  Set fso = nothing
  Set Engine = nothing
  response.write "数据库压缩成功!"
 Else
  response.write "数据库没有找到!"
 End If
end sub

sub RestoreData()
 dim backpath,fso
 backpath=request.form("backpath")
 if backpath="" then
  FoundErr=True
  ErrMsg=ErrMsg & "<li>请指定原备份的数据库文件名！</li>"
  exit sub 
 end if
 backpath=server.mappath(backpath)
 Set Fso=server.createobject("scripting.filesystemobject")
 if fso.fileexists(backpath) then       
  fso.copyfile Backpath,Dbpath
  response.write "成功恢复数据！"
 else
  response.write "找不到指定的备份文件！"
 end if
end sub

海外公司注册、海外银行开户、跨境平台代入驻、VAT、EPR等知识和在线办理：https://www.xlkjsw.com

原标题：ASP实现备份、压缩、还原数据库

关键词：ASP